네이버 클라우드

구독
다운로드 31
업데이트 2023. 8. 5.

사용 매뉴얼

대시보드

네이버 클라우드 앱은 아래의 대시보드를 내장 지원합니다.

API 감사 대시보드

네이버 클라우드의 Cloud Activity Tracer 서비스 API를 호출하여 실시간으로 클라우드 행위를 모니터링합니다.

네이버 클라우드 API 감사

최근 24시간 서버 생성

최근 24시간 내 새로 생성된 서버 인스턴스 수를 표시합니다.

ncloud-activities duration=1d
| search action_name == "Create Server Instance"
| stats count

최근 24시간 서버 반납

최근 24시간 내 반납된 서버 인스턴스 수를 표시합니다. 의도하지 않은 서버 반납으로 인해 데이터 파괴가 발생할 수 있으므로 유의해야 합니다.

ncloud-activities duration=1d
| search action_name == "Server Termination"
| stats count

최근 24시간 ACG 변경

최근 24시간 내 ACG (Access Control Group) 설정 변경 횟수를 표시합니다. 의도하지 않은 방화벽 정책 변경은 공격 표면 (Attack Surface) 노출을 유발할 수 있습니다.

ncloud-activities duration=1d
| search action_name == "Update ACG*" and action_name == "*(Request)"
| stats count

최근 24시간 액세스 키 생성

최근 24시간 내 액세스 키 생성 횟수를 표시합니다. 액세스 키의 발급과 권한 범위는 최소화하여 관리해야 합니다.

ncloud-activities duration=1d
| search action_name == "Create access key"
| stats count

API 호출 추이

최근 일주일의 API 유형별 호출 추이를 10분 단위로 집계하여 누적 막대 차트로 표시합니다. 통상적이지 않은 시간대에 인가되지 않은 작업이 발생했는지 확인할 수 있습니다.

ncloud-activities duration=1w 
| timechart span=10m count by action_name

API 호출 내역

네이버 클라우드 API 호출 내역을 표시합니다. 매개변수까지 세부사항을 포함하여 확인할 수 있습니다.

ncloud-activities duration=1w
| rename _time as 시각, src_ip as 출발지IP, user as 계정, source_type as 요청구분, action_name as 작업내역, action_result_type as 작업결과, product_name as 상품명, resource_type as 리소스유형, resource_name as 리소스이름, region_name as 리전, platform_type as 플랫폼, params as 매개변수
| fields 시각, 리전, 출발지IP, 계정, 요청구분, 작업내역, 작업결과, 상품명, 리소스유형, 리소스이름, 플랫폼, 매개변수
| limit 100

로그인 대시보드

네이버 클라우드 로그인 이상징후를 확인할 수 있도록 시각화 합니다.

네이버 클라우드 로그인 대시보드

최근 24시간 콘솔 로그인 실패

최근 24시간 내 포탈 로그인 실패 횟수를 표시합니다.

ncloud-activities duration=1d
| search source_type == "PORTAL" and action_name == "Login" and action_result_type == "FAIL"
| stats count

최근 24시간 로그인 계정

최근 24시간 내 포탈에 로그인 한 유일한 계정의 수를 표시합니다.

ncloud-activities duration=1d
| search source_type == "PORTAL" and action_name == "Login" and action_result_type == "SUCCESS"
| eval user = valueof(params, "userName")
| stats dc(user) as count

콘솔 로그인 국가

최근 24시간 내 콘솔에 로그인한 국가를 표시합니다. 허용되지 않은 국가에서 접속한 이력이 있는지 직관적으로 파악할 수 있습니다.

ncloud-activities duration=1d
| search source_type == "PORTAL" and action_name == "Login" and action_result_type == "SUCCESS"
| lookup geoip src_ip output country 
| stats count by country

최근 24시간 콘솔 로그인 실패 IP 주소

최근 24시간 내 콘솔 로그인에 실패한 출발지 IP 주소를 표시합니다.

ncloud-activities duration=1d
| search source_type == "PORTAL" and action_name == "Login" and action_result_type == "FAIL"
| stats count by src_ip 
| sort -count
| lookup geoip src_ip output country
| eval src = concat("(", country, ") ", string(src_ip))

최근 로그인 내역

최근 로그인 내역을 표시합니다. 브라우저 에이전트를 포함하여 표시하므로 기존 IP 주소와 장치에서 접속한 것이 맞는지 점검할 수 있습니다.

ncloud-activities duration=1w
| search source_type == "PORTAL" and action_name == "Login"
| eval 계정 = valueof(params, "userName"), 브라우저 = valueof(params, "userAgent"), 계정유형 = valueof(params, "userType")
| rename _time as 시각, src_ip as 출발지IP, action_result_type as 결과 | lookup geoip 출발지IP output country as 국가
| fields 시각, 출발지IP, 국가, 계정유형, 계정, 결과, 브라우저
| limit 100

청구 비용 대시보드

네이버 클라우드 청구 비용 대시보드

청구 금액

이번 달 청구 예정 금액을 표시합니다. 사용 금액에서 할인 금액을 모두 제외한 금액입니다.

ncloud-monthly-costs-by-contract
| stats sum(cost) as cost by month

사용 금액

이번 달 사용한 금액을 표시합니다. 할인과 관계없이 실제 서비스 사용량으로 계산된 금액입니다.

ncloud-monthly-costs-by-contract
| stats sum(used) as used by month

프로모션 할인

크레딧 사용 등 프로모션으로 할인된 금액을 표시합니다.

ncloud-monthly-costs-by-contract
| stats sum(promotion_discount) as promotion_discount by month

약정 할인

약정으로 할인된 금액을 표시합니다.

ncloud-monthly-costs-by-contract
| stats sum(promise_discount) as promise_discount by month

회원 요금제 할인

회원 요금제로 할인된 금액을 표시합니다.

ncloud-monthly-costs-by-contract
| stats sum(member_discount) as member_discount by month

회원약정 할인

회원약정 요금제로 할인된 금액을 표시합니다.

ncloud-monthly-costs-by-contract
| stats sum(member_promise_discount) as member_promise_discount by month

지역별 분포

리전별 사용 금액을 집계하여 표시합니다.

ncloud-monthly-costs-by-contract
| eval region = case(region == "KR", "수도권", region == "KRS", "남부권", region == "COM", "공통", region)
| stats sum(used) as used by region

서비스별 비용 분포

상품 유형별 사용 금액을 집계하여 표시합니다.

ncloud-monthly-costs-by-contract
| stats sum(used) as used by product_name
| search used > 0 
| sort -used

서비스 이용 내역

상품 및 리전별 서비스 이용 금액을 집계하여 표시합니다.

ncloud-monthly-costs-by-contract
| eval total_discount = promotion_discount + promise_discount + member_discount + member_promise_discount + etc_discount
| stats sum(used) as used, sum(total_discount) as total_discount by month, product_name, region
| search used > 0 
| eval demand_cost = used - total_discount
| eval region = case(region == "KR", "수도권", region == "KRS", "남부권", region == "COM", "공통", region)
| rename month as 청구월, product_name as 서비스, region as 리전, used as 사용금액, total_discount as 할인금액, demand_cost as 청구금액
| fields 청구월, 서비스, 리전, 사용금액, 할인금액, 청구금액
| sort -사용금액

서버 대시보드

네이버 클라우드 서버 대시보드

전체 서버 수

모든 리전의 서버 인스턴스 수를 표시합니다.

ncloud-servers | stats count

운영 서버 수

모든 리전에서 현재 운영중인 상태의 서버 인스턴스 수를 표시합니다.

ncloud-servers
| search status == "RUN"
| stats count

서버 구성 통계

모든 리전에서 CPU, 메모리 등 서버 구성별 서버 인스턴스 수를 집계하여 표시합니다.

ncloud-servers
| eval memGB = floor(memory_size / 1024 / 1024 / 1024)
| eval type = concat("[", server_type_name, "] ", cpu_count, "vCPU, ", memGB, "GB MEM")
| stats count by type

서버 목록

모든 리전에 존재하는 서버 인스턴스 목록을 표시합니다.

ncloud-servers 
| join vpc_no [ ncloud-vpcs | fields vpc_no, vpc_name ]
| join subnet_no [ ncloud-subnets | fields subnet_no, subnet_name ]
| eval memGB = floor(memory_size / 1024 / 1024 / 1024) 
| eval 서버구성 = concat("[", server_type_name, "] ", cpu_count, "vCPU, ", memGB, "GB MEM") 
| eval 상태 = case(status == "RUN", "운영중", status == "NSTOP", "정지", status) 
| eval region = case(region == "KR", "수도권", region == "KRS", "남부권", region)
| rename region as 리전, no as 번호, name as 서버이름, public_ip as 공인IP, platform_type_name as 플랫폼,  login_key_name as 인증키, created as 생성일시, uptime as 구동일시, vpc_name as VPC, subnet_name as 서브넷
| fields 번호, 리전, VPC, 서버이름, 서버구성, 상태, 공인IP, 서브넷, 플랫폼, 인증키, 생성일시, 구동일시